cloudflared/vendor/github.com/grpc-ecosystem/grpc-opentracing/java/build.gradle

description = "grpc-java: OpenTracing"

group = "io.opentracing.contrib"
version = '0.2.0'
version = '0.3.0'

apply plugin: 'java'
apply plugin: 'maven'
apply plugin: 'signing'

sourceSets {
    main {
        java {
            srcDirs = ['src/main/java']
        }
    }
    test {
        java {
            srcDirs = ['src/test/java', 'src/testgen']
        }
    }
}

task javadocJar(type: Jar) {
    classifier = 'javadoc'
    from javadoc
}

task sourcesJar(type: Jar) {
    classifier = 'sources'
    from sourceSets.main.allSource
}

artifacts {
    archives jar

    archives javadocJar
    archives sourcesJar
}

signing {
    sign configurations.archives
}

repositories {
    mavenCentral()
}

jar {
    baseName 'grpc-opentracing'
    version = '0.2.0'
    version = '0.3.0'
}

dependencies {
    compile 'io.grpc:grpc-core:1.6.1'
    compile 'io.opentracing:opentracing-api:0.30.0'
    testCompile 'io.opentracing:opentracing-mock:0.30.0'
    testCompile 'io.grpc:grpc-protobuf:1.6.1'
    testCompile 'io.grpc:grpc-netty:1.6.1'
    testCompile 'io.grpc:grpc-stub:1.6.1'
    testCompile 'junit:junit:4.12'
}

// Allow for automatic promotion and release to Maven Central
buildscript {
    repositories {
        mavenCentral()
    }
    dependencies {
        classpath "io.codearte.gradle.nexus:gradle-nexus-staging-plugin:0.5.3"
    }
}
apply plugin: 'io.codearte.nexus-staging'

nexusStaging {
    packageGroup = "io.opentracing"
}

uploadArchives {
    repositories {
        mavenDeployer {
            beforeDeployment { MavenDeployment deployment -> signing.signPom(deployment) }

            repository(url: "https://oss.sonatype.org/service/local/staging/deploy/maven2/") {
                authentication(userName: sonatypeUsername, password: sonatypePassword)
            }

            snapshotRepository(url: "https://oss.sonatype.org/content/repositories/snapshots/") {
                authentication(userName: sonatypeUsername, password: sonatypePassword)
            }

            pom.project {
                name 'grpc-opentracing'
                packaging 'jar'
                // optionally artifactId can be defined here
                description 'Provides support for integrating OpenTracing in grpc clients and servers.'
                url 'http://www.github.com/grpc-ecosystem/grpc-opentracing'

                scm {
                    url 'scm:git@github.com:grpc-ecosystem:grpc-opentracing.git'
                    connection 'scm:git@github.com:grpc-ecosystem/grpc-opentracing.git'
                    developerConnection 'scm:git@github.com:grpc-ecosystem/grpc-opentracing.git'
                }

                licenses {
                    license {
                        name 'BSD-3'
                        url 'https://opensource.org/licenses/BSD-3-Clause'
                    }
                }

                developers {
                    developer {
                        name 'Kathy Camenzind'
                        email 'kcamenzind@lightstep.com'
                    }
                }

            }
        }
    }
}